.emacs.d/init.el

;;; init.el --- tastytea's Emacs init file.
;; Time-stamp: <2019-04-25T21:04:24+00:00>

;;; Commentary:
;; I am using this file with Emacs 26, but most of it will probably work with
;; Emacs 24 and above.

;;; Code:
;;;;;;;;;;;;;;;;;;;; Packages ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(require 'package)
(add-to-list 'package-archives
             '("melpa-stable" . "https://stable.melpa.org/packages/") t)
(add-to-list 'package-archives
             '("melpa" . "https://melpa.org/packages/") t)
(setq package-archive-priorities '(("gnu"          . 1)
                                   ("melpa-stable" . 2)
                                   ("melpa"        . 3)))
(package-initialize)

;; Add path for custom packages.
(add-to-list 'load-path "~/.emacs.d/custom-packages/")

;; Install use-package if necessary.
(unless (package-installed-p 'use-package)
  (package-refresh-contents)
  (package-install 'use-package))

(eval-when-compile
  (require 'use-package))

;; Always install packages if they are not present.
(require 'use-package-ensure)
(setq use-package-always-ensure t)

;; autocompile files as needed.
(use-package auto-compile
  :custom
  ;; Use uncompiled file if it is newer than the compiled one.
  (load-prefer-newer t)
  :config
  (auto-compile-on-load-mode))

;; ;; Benchmark for startup-file.
;; (use-package benchmark-init
;;   :config
;;   ;; To disable collection of benchmark data after init is done.
;;   (add-hook 'after-init-hook 'benchmark-init/deactivate))

;; Update packages if at least 7 days have passed.
(use-package auto-package-update
  :custom
  (auto-package-update-delete-old-versions t)
  (auto-package-update-interval 7)
  (auto-package-update-hide-results nil)
  :config
  (auto-package-update-maybe))

;;;;;;;;;;;;;;;;;;;; Global variables ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Determine if we run on a slow computer.
(defvar slow-computer nil)
(if (member (system-name) '("steuerbeamter" "azimuth" "localhost"))
    (setq slow-computer t))             ; localhost is schnibble

;; Show manpages and error messages from compilers in English.
(setenv "LANG" "en_US.utf8")

;;;;;;;;;;;;;;;;;;;; Configure some essential things ;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Set garbage collection threshold to 100 MiB (or 20 MiB) to speed up init.
;; It is reset at the end of the file.
(if slow-computer
    (setq gc-cons-threshold (* 20 1024 1024))
  (setq gc-cons-threshold (* 100 1024 1024)))

(use-package emacs
  :init
  ;; Banish customizations to another file.
  (setq custom-file (concat user-emacs-directory "custom.el"))

  :custom
  (inhibit-startup-screen t)
  (inhibit-startup-echo-area-message t)

  (backup-directory-alist            ; Save backups in ~/.emacs.d/backups/.
   `(("." . ,(concat user-emacs-directory "backups"))))
  (delete-old-versions t)            ; Delete old backups.
  (kept-new-versions 6)              ; Keep 6 newest backups.
  (backup-by-copying t)              ; Copy to backup folder.
  (version-control t)                ; Append version numbers to file names.
  (auto-save-file-name-transforms    ; Save auto-saves in ~/.emacs.d/backups/.
   `((".*" ,(concat user-emacs-directory "backups/") t)))

  (user-full-name "tastytea")
  (user-mail-address "tastytea@tastytea.de")
  (mouse-wheel-scroll-amount '(1 ((shift) . 1))) ; Scroll 1 line at a time.
  ;; Paste text where the cursor is, not where the mouse is.
  (mouse-yank-at-point t)
  (initial-scratch-message nil)      ; Make scratch buffer empty,
  (initial-major-mode 'text-mode)    ; and select text-mode.
  (require-final-newline t)          ; Always add newline at end of file.

  :config
  (defalias 'yes-or-no-p 'y-or-n-p)  ; Just type y/n instead of yes/no.

  (defun my/set-fill-column-80 ()
    "Set fill-column to 80."
    (set-fill-column 80))

  ;; kill-region (cut) and kill-ring-save (copy) act on the current line if no
  ;; text is visually selected.
  ;; https://www.emacswiki.org/emacs/WholeLineOrRegion
  (put 'kill-ring-save 'interactive-form
       '(interactive
         (if (use-region-p)
             (list (region-beginning) (region-end))
           (list (line-beginning-position) (line-beginning-position 2)))))
  (put 'kill-region 'interactive-form
       '(interactive
         (if (use-region-p)
             (list (region-beginning) (region-end))
           (list (line-beginning-position) (line-beginning-position 2)))))

  (delete-selection-mode t)          ; Delete selection when you start to write.
  (savehist-mode t)                  ; Save minibuffer history.

  :hook
  (prog-mode . my/set-fill-column-80)
  (conf-mode . my/set-fill-column-80)
  (text-mode . auto-fill-mode))      ; Enable word-wrapping at fill-column.

;; Save cursor position.
(use-package saveplace
  :config
  (save-place-mode t))

;; Scroll before cursor has reached top/bottom.
;; Way too slow with fci-mode, highlight-indent-guides, or whitespace-mode.
;; (use-package smooth-scrolling
;;   :config
;;   (smooth-scrolling-mode 1))

;; ;; Never recenter cursor while scrolling.
;; (setq scroll-conservatively 101)

;;;;;;;;;;;;;;;;;;;; Keybindings ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(use-package bind-key
  :init
  (defun my/delete-word (arg)
    "Delete characters forward until encountering the end of a word.
With argument, do this that many times."
    (interactive "p")
    (if (use-region-p)
        (delete-region (region-beginning) (region-end))
      (delete-region (point) (progn (forward-word arg) (point)))))

  (defun my/backward-delete-word (arg)
    "Delete characters backward until encountering the end of a word.
With argument, do this that many times."
    (interactive "p")
    (my/delete-word (- arg)))
  :config
  (bind-keys
   ;; Switch window
   ("C-<tab>"       . other-window)
   ;; Reduce whitespace around cursor to 0 or 1, according to context.
   ("C-S-<delete>"  . fixup-whitespace)
   ;; Scroll without moving the cursor.
   ("M-<down>"      . scroll-up-line)
   ("M-<up>"        . scroll-down-line)
   ;; Delete words without storing them in the kill buffer.
   ("C-<delete>"    . my/delete-word)
   ("C-<backspace>" . my/backward-delete-word)))

;;;;;;;;;;;;;;;;;;;; Programming / general ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Online documentation mode.
(use-package eldoc
  :hook
  (prog-mode . turn-on-eldoc-mode))

;; Syntax checking with many plugins.
(unless slow-computer
  (use-package flycheck
    :config
    (global-flycheck-mode)))

;; Autocompletion mode with many plugins.
(unless slow-computer
  (use-package company
    :custom
    ;; Show suggestions after entering one character.
    (company-minimum-prefix-length 1)
    ;; Wrap around at end/beginning of list.
    (company-selection-wrap-around t)
    ;; Align annotation to the right border.
    (company-tooltip-align-annotations t)
    :bind
    (:map company-active-map
          ("<return>" . nil)           ; Disable completion on return.
          ("RET" . nil)                ; https://emacs.stackexchange.com/a/13290
          ("<tab>" . company-complete-selection) ; Make tab work in lists.
          ("TAB" . company-complete-selection))
    :hook
    (after-init . global-company-mode)))

;; Fuzzy autocompletion for company.
(use-package company-flx
  :after company
  :config
  (company-flx-mode +1))

(use-package company-statistics
  :after company
  :hook
  (after-init-hook . company-statistics-mode))

;; Set default indentation.
(setq-default indent-tabs-mode nil
              tab-width 4)

;; Guess indentation.
(use-package dtrt-indent
  :hook
  (prog-mode . dtrt-indent-mode))

;; Automatic project management.
(unless slow-computer
  (use-package projectile
    :after neotree
    :init
    (defun my/projectile-kill-buffers-and-change-tabbar-grouping ()
      "Kill project buffers and change tabbar-ruler grouping to user-buffers."
      (interactive)
      (projectile-kill-buffers)
      (tabbar-ruler-group-user-buffers)
      (neotree-hide))
    (defvar my/cmake-compile-command    ; cmake command for compiling with 1
      (concat "cmake --build . -- -j"   ; core less than available.
              (substring (shell-command-to-string "nproc --ignore=1") 0 -1)))
    :custom
    (projectile-project-compilation-dir "build")
    (projectile-switch-project-action 'neotree-projectile-action)
    (projectile-project-configure-cmd
     "cmake -DCMAKE_BUILD_TYPE=Debug -DCMAKE_EXPORT_COMPILE_COMMANDS=ON \
-GUnix\\ Makefiles ..")
    :config
    (setq projectile-project-compilation-cmd (concat my/cmake-compile-command
                                                     " && ctest -Q"))
    (projectile-mode +1)
    (put 'projectile-project-compilation-cmd 'safe-local-variable #'stringp)
    ;; Mark variable as safe. This prevents prompts when using .dir-locals.el.
    (put 'projectile-project-configure-cmd 'safe-local-variable #'stringp)
    :bind
    ("C-c p" . 'projectile-command-map)
    (:map projectile-command-map
          ("k" . 'my/projectile-kill-buffers-and-change-tabbar-grouping))))

;; Highlight TODO, FIXME, NOTE and so on.
(use-package hl-todo
  :bind
  (:map hl-todo-mode-map
        ("C-c t" . hl-todo-occur))
  :hook
  (prog-mode . hl-todo-mode))

;; Better commenting.
(use-package smart-comment
  :bind
  ("C-x c" . smart-comment))

;; Toggle betweeen beginning/end of line and beginning/end of code.
(use-package mwim
  :bind
  ("<home>" . mwim-beginning-of-line-or-code)
  ("<end>"  . mwim-end-of-line-or-code))

;; Auto-type closing brackets.
(electric-pair-mode t)

;; Fold code.
(use-package fold-dwim
  :bind
  ("<f7>"  . fold-dwim-toggle)
  ("C-x t" . fold-dwim-toggle)
  :hook
  (prog-mode . hs-minor-mode))

;; ;; Highlight indentation levels.
;; (use-package highlight-indent-guides
;;   :custom
;;   (highlight-indent-guides-method 'character)
;;   (highlight-indent-guides-responsive 'top)
;;   :hook
;;   (prog-mode . highlight-indent-guides-mode))

;; Tries to find points of interest and jumps to them.
(use-package imenu-anywhere
  :after ido-completing-read+
  :bind
  ("M-i" . imenu-anywhere))

(use-package highlight-doxygen
  :custom-face
  (highlight-doxygen-comment ((t (:inherit font-lock-comment-face
                                          :foreground "#667788"))))
  (highlight-doxygen-code-block ((t (:inherit highlight-doxygen-comment-face))))
  :hook
  (prog-mode . highlight-doxygen-mode))

(use-package dumb-jump
  :bind
  ("M-." . dumb-jump-go)
  ("M-," . dumb-jump-back))

;;;;;;;;;;;;;;;;;;;; Programming / C++ ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Set coding style.
(use-package cc-mode
  :ensure nil                           ; Included in Emacs.
  :config
  (c-add-style "tastytea"
               '("bsd"
                 (c-basic-offset . 4)))
  :custom
  (c-default-style "tastytea"))

(unless slow-computer
  ;; irony communicates with a clang-server. It needs compile_commands.json.
  (use-package irony
    :after yasnippet
    :hook
    (c++-mode        . irony-mode)
    (c-mode          . irony-mode)
    (irony-mode      . irony-cdb-autosetup-compile-options)
    :config
    ;; If irony server is not installed, install it.
    (unless (irony--find-server-executable)
      (call-interactively #'irony-install-server)))

  ;; Eldoc shows argument list of the function you are currently writing.
  (use-package irony-eldoc
    :after (eldoc irony)
    :hook
    (irony-mode . irony-eldoc))

  ;; Syntax checker.
  (use-package flycheck-irony
    :after (flycheck irony)
    :hook
    (flycheck-mode-hook . flycheck-irony-setup))

  ;; Auto-complete integration.
  (use-package company-irony
    :after (company irony)
    :config
    (add-to-list 'company-backends 'company-irony))

  ;; Auto-complete headers
  (use-package company-irony-c-headers
    :after (company-irony)
    :config
    (add-to-list 'company-backends 'company-irony-c-headers))

  ;; cmake integration.
  (use-package cmake-ide
    :after irony
    :custom
    (cmake-ide-build-dir "build")
    ;; (cmake-ide-cmake-args '("-DCMAKE_BUILD_TYPE=Debug"
    ;;                         "-DCMAKE_EXPORT_COMPILE_COMMANDS=ON"
    ;;                         "-GUnix Makefiles"))
    (cmake-ide-cmake-opts "")           ; Use the already configured options.
    :config
    (cmake-ide-setup))
) ; unless slow-computer

;; GUI for gdb and other debuggers.
(use-package realgud
  :after cc-mode
  :config
  (defun my/load-realgud ()
    (load-library "realgud"))
  :bind
  (:map c-mode-base-map
        ("C-c g" . my/load-realgud)))

;;;;;;;;;;;;;;;;;;;; Appearance ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Hide toolbar.
(tool-bar-mode -1)

;; Put scrollbar to the right side.
(if (display-graphic-p)
    (set-scroll-bar-mode 'right))

;; Icons (required by doom).
(use-package all-the-icons
  :config
  (unless (member "all-the-icons" (font-family-list))
    (all-the-icons-install-fonts t)))

;; Themes for doom-modeline.
(unless slow-computer
  (use-package doom-themes
    :after (all-the-icons neotree)
    :custom
    (doom-neotree-file-icons 'icons)
    :custom-face
    (font-lock-comment-face ((t (:inherit font-lock-comment-face
                                          :foreground "#667755"))))
    :config
    (load-theme 'doom-molokai t)
    (doom-themes-neotree-config)))

;; Neat modeline.
(use-package doom-modeline
  :after all-the-icons
  :init
  (column-number-mode t)                ; Show column numbers in modeline.
  (size-indication-mode)                ; Buffer size display in the modeline.
  :config
  (setq doom-modeline-minor-modes nil
        ;; doom-modeline-buffer-file-name-style 'relative-to-project
        doom-modeline-buffer-file-name-style 'truncate-except-project)
  :hook
  (after-init . doom-modeline-mode))

;; Miscellaneous visual improvements.
(add-to-list 'default-frame-alist       ; Set default font.
             '(font . "Source Code Pro-10"))
(global-hl-line-mode t)                 ; Highlight current line.
(show-paren-mode t)                     ; Visualize matching parens.
;; Show line numbers on the left side of the buffer.
(use-package display-line-numbers
  :if (>= emacs-major-version 26)
  :config
  (global-display-line-numbers-mode))

;; Colored man pages.
(use-package man
  :defer t
  :custom-face
  (Man-overstrike ((t (:inherit font-lock-type-face :bold t))))
  (Man-underline  ((t (:inherit font-lock-keyword-face :underline t)))))

;;;;;;;;;;;;;;;;;;;; Misc ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Show directory tree in a window.
(use-package neotree
  :demand t
  :after all-the-icons
  :custom
  (neo-smart-open t)
  (neo-show-updir-line t)           ; Disabled by doom-themes?
  (neo-window-width 40)
  (neo-show-hidden-files t)
  :bind
  ("<f8>" . neotree-toggle))

;; Git integration.
(use-package git-commit)
(unless slow-computer
  (use-package magit
    :config
    (defun my/magit-kill-buffers (arg)
      "Restore window configuration and kill all Magit buffers."
      (interactive)
      (let ((buffers (magit-mode-get-buffers)))
        (magit-restore-window-configuration)
        (mapc #'kill-buffer buffers)))
    :bind
    ("C-x g"   . magit-status)
    ("C-x M-g" . magit-dispatch)
    :custom
    (magit-bury-buffer-function 'my/magit-kill-buffers)))

;; ;; Draw line in column 80
;; (use-package fill-column-indicator
;;   :after company
;;   :config
;;   ;; Fix bug with fci + popup menus.
;;   (defun my/fci-mode-enabled-p ()
;;     (symbol-value 'fci-mode))
;;   (defvar-local my/fci-enabled nil)
;;   ;; company:
;;   (defun my/on-off-fci-before-company(command)
;;     "Turn fci-mode off while displaying popups in company."
;;     (when (string= "show" command)
;;       (setq-local my/fci-enabled (my/fci-mode-enabled-p))
;;       (if my/fci-enabled
;;           (turn-off-fci-mode)))
;;     (when (string= "hide" command)
;;       (if my/fci-enabled
;;           (turn-on-fci-mode))))
;;   (advice-add 'company-call-frontends :before #'my/on-off-fci-before-company)
;;   ;; popup:
;;   (defadvice popup-create (before my/popup-suppress-fci-mode activate)
;;     "Suspend fci-mode while popups are visible."
;;     (setq-local my/fci-enabled (my/fci-mode-enabled-p))
;;     (if my/fci-enabled
;;         (turn-off-fci-mode)))
;;   (defadvice popup-delete (after my/popup-restore-fci-mode activate)
;;     "Restore fci-mode when all popups have closed."
;;     (if my/fci-enabled
;;         (turn-on-fci-mode)))
;;   :hook
;;   (prog-mode . fci-mode)
;;   (conf-mode . fci-mode))

;; Interactive substring matching.
(use-package ido
  :defer 5
  :config
  (ido-mode t)
  (ido-everywhere t))

;; Flexible matching for ido.
(use-package flx-ido
  :after ido
  :custom
  (ido-enable-flex-matching t)
  (ido-ignore-extensions t)    ; Ignore extension like ~ and .o.
  (ido-use-virtual-buffers t)  ; Use history of recently opened buffers.
  (recentf-max-saved-items 40) ; Keep this number of buffers in history.
  :config
  (flx-ido-mode t))

;; Replaces stock emacs completion with ido completion wherever it is possible.
(unless slow-computer
  (use-package ido-completing-read+
    :after ido
    :config
    (ido-ubiquitous-mode t)))

;; Advanced tab bar.
(unless slow-computer
  (use-package mode-icons)
  (use-package tabbar-ruler
    :pin melpa                          ; Faces are not correctly applied,
    :after (projectile mode-icons)      ; version from >=2016-08-02 is needed.
    :custom
    (tabbar-ruler-global-tabbar t)
    (tabbar-ruler-global-ruler t)
    :config
    ;; (tabbar-ruler-group-by-projectile-project) ; Group by projectile.
    ;; (tabbar-ruler-group-buffer-groups)         ; Group by file type.
    (tabbar-ruler-group-user-buffers)          ; Group by frame.
    (mode-icons-mode 0)                        ; Disable modeline symbols.

    (add-hook 'projectile-after-switch-project-hook ; Does not work under :hook.
              'tabbar-ruler-group-by-projectile-project)

    ;; Show tabbar after 5 seconds idle.
    (run-with-idle-timer 5 t (lambda ()
                               (when tabbar-ruler-tabbar-off
                                 (tabbar-mode 1)
                                 (setq tabbar-ruler-tabbar-off nil)
                                 (ruler-mode -1)
                                 (setq tabbar-ruler-ruler-off t))))
    :bind
    ("C-<prior>" . 'tabbar-ruler-tabbar-backward-tab)
    ("C-<next>"  . 'tabbar-ruler-tabbar-forward-tab)
    :custom-face
    (tabbar-selected ((t
                       (:background "gray11"
                        :foreground "light gray"
                        :family "Sans Serif"
                        :bold t))))
    (tabbar-unselected ((t
                         (:background "gray18"
                          :foreground "dark gray"
                          :family "Sans Serif"
                          :italic t))))
    (tabbar-modified ((t
                       (:foreground "brown2"
                        :italic t
                        :bold nil))))
    (ruler-mode-default ((t
                          (:inherit default
                           :background "gray18"
                           :foreground "dim gray"
                           :box nil))))
    (ruler-mode-column-number ((t
                                (:inherit ruler-mode-default
                                 :foreground "dark gray"))))
    ))

;; Visualize whitespace.
(use-package whitespace
  :after company
  :config
  (delete 'newline-mark whitespace-style) ; Don't paint $ at eol.
  (delete 'lines whitespace-style)        ; Don't paint lines red if too long.
  ;; Workaround to not show dots in popup menus.
  (defun my/whitespace-mode-enabled-p ()
    (symbol-value 'whitespace-mode))
  (defvar-local my/ws-enabled nil)
  ;; company:
  (defun my/on-off-whitespace-before-company(command)
    (when (string= "show" command)
      (setq-local my/ws-enabled (my/whitespace-mode-enabled-p))
      (if my/ws-enabled
          (whitespace-mode -1)))
    (when (string= "hide" command)
      (if my/ws-enabled
          (whitespace-mode t))))
  (advice-add 'company-call-frontends
              :before #'my/on-off-whitespace-before-company)
  ;; popup:
  (defadvice popup-create (before my/popup-suppress-whitespace-mode activate)
    "Suspend whitespace-mode while popups are visible."
    (setq-local my/ws-enabled (my/whitespace-mode-enabled-p))
    (if my/ws-enabled
        (whitespace-mode -1)))
  (defadvice popup-delete (after my/popup-restore-whitespace-mode activate)
    "Restore whitespace-mode when all popups have closed."
    (if my/ws-enabled
        (whitespace-mode t)))
  :bind
  ("C-x w" . 'whitespace-mode)
  :hook
  (prog-mode . whitespace-mode)
  (conf-mode . whitespace-mode)
  :custom-face
  (whitespace-space ((nil :foreground "gray18"))))

;; Spell checking.
(if (or (executable-find "aspell")
        (executable-find "hunspell")
        (executable-find "ispell"))
    (unless slow-computer
      (use-package flyspell
        :custom
        (ispell-dictionary "english")
        :config
        (defun my/toggle-flyspell ()
          "Toggle flyspell-mode and run flyspell-buffer after activating."
          (interactive)
          (if (bound-and-true-p flyspell-mode)
              (flyspell-mode 0)
            (flyspell-mode)
            (flyspell-buffer)))
        (defun my/flyspell-german ()
          "Set dictionary to german."
          (ispell-change-dictionary "german"))
        :bind
        ("<f6>" . my/toggle-flyspell)
        (:map flyspell-mode-map
              ("C-;" . nil))            ; iedit needs C-;.
        :hook
        ;; Spellcheck comments.
        (prog-mode . flyspell-prog-mode)
        ;; Spellcheck LaTeX
        (LaTeX-mode . my/flyspell-german)
        (LaTeX-mode . flyspell-mode))))

;; Multiple cursors.
(use-package multiple-cursors
  :init
  (global-unset-key (kbd "M-<down-mouse-1>"))
  :bind
  ("C-x M-m"     . mc/edit-lines)
  ("M-<mouse-1>" . mc/add-cursor-on-click))

;; If 2 files have the same name, append directory name after the filename.
(use-package uniquify
  :ensure nil                           ; Included in Emacs.
  :custom
  (uniquify-after-kill-buffer-p t)
  (uniquify-buffer-name-style 'post-forward)
  (uniquify-strip-common-suffix t))

;; Delete old buffers.
;; https://www.emacswiki.org/emacs/CleanBufferList
(use-package midnight
  :defer 10
  :init
  (setq midnight-delay 30                     ; 30 seconds after "midnight"
        midnight-period (* 2 60 60))          ; Clean every 2 hours.
  :custom
  (clean-buffer-list-delay-general 1)         ; Clean normal bufs after 1d.
  (clean-buffer-list-delay-special (* 30 60)) ; Clean special bufs after 30m.
  :config
  (setq clean-buffer-list-kill-regexps        ; Add these to special buffers.
        (nconc clean-buffer-list-kill-regexps
               '("\\`magit-?.*:"
                 "\\.log\\'"
                 "\\`'\\*rdm\\*\\'")))
  (midnight-mode t))

;; The string Time-stamp: <> in the first 8 lines of the file will be updated
;; with the current timestamp.
(use-package time-stamp
  :custom
  (time-stamp-format "%:y-%02m-%02dT%02H:%02M:%02S+00:00")
  (time-stamp-time-zone t)             ; Set to UTC until ISO 8601 is supported.
  :hook
  (before-save . time-stamp))

;; Edit multiple regions in the same way simultaneously.
(use-package iedit
  :bind
  ("C-;" . iedit-mode))

;; Mode for writing blog posts with hugo.
(if (string= (system-name) "ventiloplattform")
    (use-package easy-hugo
      :custom
      (easy-hugo-basedir "~/Projekte/www/blog.tastytea.de/")
      (easy-hugo-url "https://blog.tastytea.de")
      (easy-hugo-previewtime "300")
      (easy-hugo-postdir "content/posts")
      (easy-hugo-default-ext ".adoc")
      :bind
      ("C-x M-h" . easy-hugo)
      :mode
      ;; The mode is not turned on?
      ("\\`'\\*Easy-hugo\\*\\'" . easy-hugo-mode)))

;; A template system.
(use-package yasnippet)

;; Automatically insert text in new files.
(use-package autoinsert
  :after yasnippet
  :init
  (defun my/autoinsert-yas-expand()
    "Replace text in yasnippet template."
    (yas-minor-mode t)
    (yas-expand-snippet (buffer-string) (point-min) (point-max)))
  :config
  (add-to-list 'auto-insert-alist
               '(("\\.\\(cpp\\|cc\\|cxx\\|c\\+\\+\\)\\'" . "C++ program") .
                 ["cpp" my/autoinsert-yas-expand]))
  (add-to-list 'auto-insert-alist
               '(("\\.\\(hpp\\|hh\\|hxx\\|h\\+\\+\\)\\'" . "C++ header") .
                 ["hpp" my/autoinsert-yas-expand]))
  (add-to-list 'auto-insert-alist
               '(("\\.[1-9]\\.adoc\\'" . "AsciiDoc manpage") .
                 ["manpage.adoc" my/autoinsert-yas-expand]))
  :custom
  (auto-insert-directory (concat user-emacs-directory "auto-insert"))
  (auto-insert-query nil)               ; Don't ask before inserting.
  :hook
  (find-file . auto-insert))

;;;;;;;;;;;;;;;;;;;; LaTeX ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(if (executable-find "xetex")
    (use-package tex-site
      :ensure auctex
      :custom
      (TeX-parse-self t)               ; Enable parse on load.
      (TeX-auto-save t)                ; Enable parse on save
      (TeX-PDF-mode t)                 ; PDF mode (rather than DVI-mode)
      (TeX-engine 'xetex)
      ;; To use pdf-tools with auctex.
      ;; https://emacs.stackexchange.com/a/21764/21935
      (TeX-view-program-selection '((output-pdf "PDF Tools")))
      (TeX-view-program-list '(("PDF Tools" TeX-pdf-tools-sync-view)))
      :mode
      ("\\.tex\\'" . LaTeX-mode)
      :config
      ;; To have the buffer refresh after compilation.
      (add-hook 'TeX-after-compilation-finished-functions
                #'TeX-revert-document-buffer)))

;; Auto complete for LaTeX.
(use-package company-auctex
  :after auctex
  :hook
  (LaTeX-mode . company-auctex-init))

;;;;;;;;;;;;;;;;;;;; (X)HTML / CSS ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Use company auto-completion for (X)HTML.
(use-package company-web
  :after company
  :config
  (add-to-list 'company-backends 'company-web-html))

;;;;;;;;;;;;;;;;;;;; Other file formats ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(use-package adoc-mode
  :mode
  ("\\.adoc\\'" . adoc-mode)
  :custom-face
  ;; Style headers.
  (markup-title-0-face ((t (:inherit markup-gen-face :height 1.4))))
  (markup-title-1-face ((t (:inherit markup-gen-face :height 1.3))))
  (markup-title-2-face ((t (:inherit markup-gen-face :height 1.2))))
  (markup-title-3-face ((t (:inherit markup-gen-face :height 1.1
                                     :weight bold))))
  (markup-title-4-face ((t (:inherit markup-gen-face :height 1.0
                                     :underline t))))
  (markup-title-5-face ((t (:inherit markup-gen-face :height 1.0))))
  ;; Enlarge meta-data a bit.
  (markup-secondary-text-face ((t (:inherit markup-gen-face :height 0.9
                                     :foreground "firebrick"))))
  :hook
  (adoc-mode . auto-fill-mode)          ; Wrap at fill-column.
  (adoc-mode . my/set-fill-column-80))

(use-package markdown-mode
  :custom
  (markdown-command "cmark")
  :custom-face
  ;; Style headers.
  (markdown-header-face-1 ((t (:inherit markdown-header-face :height 1.4
                                        :weight normal))))
  (markdown-header-face-2 ((t (:inherit markdown-header-face :height 1.3
                                        :weight normal))))
  (markdown-header-face-3 ((t (:inherit markdown-header-face :height 1.2
                                        :weight normal))))
  (markdown-header-face-4 ((t (:inherit markdown-header-face :height 1.1
                                        :weight bold))))
  (markdown-header-face-5 ((t (:inherit markdown-header-face :height 1.0
                                        :weight normal :underline t))))
  (markdown-header-face-6 ((t (:inherit markdown-header-face :height 1.0
                                        :weight normal))))
  (markdown-header-face-7 ((t (:inherit markdown-header-face :height 1.0
                                        :weight normal))))
  :mode
  (("README\\.md\\'" . gfm-mode)
   ("\\.md\\'" . markdown-mode)
   ("\\.markdown\\'" . markdown-mode))
  :hook
  (markdown-mode . my/set-fill-column-80)
  (markdown-mode . auto-fill-mode))     ; Wrap at fill-column.

(use-package crontab-mode
  :mode
  ("/cron\\.d/" . crontab-mode)
  ("\\`'/etc/crontab\\'" . crontab-mode))

(use-package nginx-mode
  :defer t)

(use-package company-nginx
  :after nginx-mode
  :hook
  (nginx-mode . company-nginx-keywords))

;; View PDF files.
(use-package pdf-tools
  :custom
  (pdf-misc-print-programm "/usr/bin/lpr")
  :mode
  ("\\.pdf\\'" . pdf-tools-install))

(use-package yaml-mode
  :mode
  ("\\.yml\\'" . yaml-mode)
  :hook
  (yaml-mode . my/set-fill-column-80))

;;;;;;;;;;;;;;;;;;;; Server / Remote editing ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Edit remote files.
(unless slow-computer
  (use-package tramp
    :config
    ;; ssh is faster than scp and supports ports.
    (setq tramp-default-method "ssh")
    ;; Add verification code support.
    (customize-set-variable
     'tramp-password-prompt-regexp
     (concat
      "^.*"
      (regexp-opt
       '("passphrase" "Passphrase"
         "password" "Password"
         "Verification code")
       t)
      ".*:\0? *"))
    ;; Respect remote PATH.
    (add-to-list 'tramp-remote-path 'tramp-own-remote-path)))

;; Run server if:
;; - Our EUID is not 0,
;; - We are not logged in via SSH,
;; - It is not already running.
(unless (equal (user-real-uid) 0)
  (unless (getenv "SSH_CONNECTION")
    (use-package server
      :defer 5
      :init
      (setq server-use-tcp t
            server-port 51313
            server-auth-key ; 64 chars, saved in ~/.emacs.d/server/server.
            "phahw2ohVoh0oopheish7IVie9desh8aequeenei3uo8wahShe%thuadaeNa4ieh")
      :config
      (unless (server-running-p)
        (server-start))
      )))

;; Set garbage collection threshold to original value.
(setq gc-cons-threshold (car (get 'gc-cons-threshold 'standard-value)))

(provide 'init)
;;; init.el ends here