.emacs.d/init.d/basics/buffers.el

;;; buffers.el --- Default settings for buffers. -*- lexical-binding: t; -*-

;; Time-stamp: <2020-03-28T12:42:31+0100>

;;; Commentary:
;; * Setup scratch buffer.
;; * Set fill-column.
;; * Define which buffers should be ignored.
;; * Enable auto-fill-mode.

;;; Code:

(require 'basics/package-management)

(use-package emacs
  :custom ((initial-scratch-message nil)   ; Make scratch buffer empty,
           (initial-major-mode 'gfm-mode)) ; and select mode.
  :config (progn
            (defvar my/skippable-buffers '("^\\*" "^magit[:-]")
              "Buffer names ignored by `next-buffer' and `previous-buffer'.")
            (defvar my/never-skippable-buffers
              '("^\\*scratch\\*$" "^\\*Easy-hugo\\*$")
              "Buffer names never ignored by `next-buffer' and `previous-buffer'.")
            (defun my/buffer-predicate (buffer)
              "Return nil if buffer-name matches expression in `my/skippable-buffers'."
              (catch 'return
                ;; Return t if buffer-name is on never-skippable list.
                (dolist (expression my/never-skippable-buffers)
                  (if (string-match expression (buffer-name buffer))
                      (throw 'return t)))
                ;; Return nil if buffer-name is on skippable list.
                (dolist (expression my/skippable-buffers)
                  (if (string-match expression (buffer-name buffer))
                      (throw 'return nil)))
                t))
            (set-frame-parameter nil 'buffer-predicate 'my/buffer-predicate)

            (defun my/truncate-lines ()
              "Truncate lines in local buffer instead of wrapping them."
              (setq-local truncate-lines t)))
  :bind (("M-<left>"  . previous-buffer)
         ("M-<right>" . next-buffer))
  :hook ((prog-mode . my/truncate-lines)
         (conf-mode . my/truncate-lines)))

;; Show and select buffers. Minimal interface for recovery situations.
(use-package bs
  :bind ("C-x C-b" . bs-show))

;; Delete old buffers.
;; https://www.emacswiki.org/emacs/CleanBufferList
(use-package midnight
  :defer 10
  :init (setq midnight-delay 30            ; 30 seconds after “midnight”.
              midnight-period (* 2 60 60)) ; Clean every 2 hours.
  :custom ((clean-buffer-list-delay-general 1) ; Clean normal bufs after 1d,
           (clean-buffer-list-delay-special (* 30 60))) ; special after 30m.
  :config (progn
            (setq clean-buffer-list-kill-regexps ; Add these to special buffers.
                  (nconc clean-buffer-list-kill-regexps
                         '("^magit-?.*:"
                           "\\.log$"
                           "^\\*rdm\\*$"
                           "^\\*Backtrace\\*$"
                           "^Pfuture-Callback"
                           )))
            (midnight-mode t)))

;; Dedicate windows to “purposes”.
(use-package window-purpose
  ;; :pin melpa  ; We need > 1.7 <https://github.com/bmag/emacs-purpose/issues/158>
  :demand t                             ; projectile depends on window-purpose.
  :config (progn
            (purpose-mode)
            (add-to-list 'purpose-user-mode-purposes '(c++-mode . cpp))
            (add-to-list 'purpose-user-mode-purposes '(qml-mode . cpp))
            (add-to-list 'purpose-user-mode-purposes '(emacs-lisp-mode . elisp))
            (add-to-list 'purpose-user-mode-purposes '(ebuild-mode . ebuild))
            (add-to-list 'purpose-user-mode-purposes '(adoc-mode . adoc))
            (add-to-list 'purpose-user-mode-purposes '(markdown-mode . md))
            (add-to-list 'purpose-user-mode-purposes '(gfm-mode . md))
            (add-to-list 'purpose-user-mode-purposes '(Man-mode . help-buf))
            (add-to-list 'purpose-user-mode-purposes '(help-mode . help-buf))
            (add-to-list 'purpose-user-mode-purposes '(info-mode . help-buf))
            (add-to-list 'purpose-user-mode-purposes
                         '(compilation-mode . compile))

            (add-to-list 'purpose-special-action-sequences
                         '(help-buf purpose-display-reuse-window-buffer))
            (purpose-compile-user-configuration)

            (require 'window-purpose-x)
            ;; Assign all Magit buffers the same purpose.
            (purpose-x-magit-single-on)
            (purpose-x-kill-setup))  ; Replace killed buffers with same purpose.
  :bind (("<f2>" . purpose-toggle-window-purpose-dedicated)
         ("C-<f2>" . purpose-toggle-window-buffer-dedicated)
         ("M-<f2>" . purpose-load-window-layout)))

;; Highlight which buffer is active by dimming the others.
(use-package dimmer
  :straight (dimmer :files (:defaults (:exclude "doc/*")))
  :config (progn
            (dimmer-configure-which-key)
            (dimmer-configure-magit)
            (dimmer-mode t)))

(provide 'basics/buffers)
;;; buffers.el ends here