Improve build process.

Update CMake recipes, update xdgcfg.

CMakeLists.txt

@@ -1,50 +1,47 @@
-cmake_minimum_required (VERSION 3.2)
-project(compilescript
-        VERSION 0.4.0
-        LANGUAGES CXX
-)
+# Support version 3.6 and above, but use policy settings up to 3.14.
+# 3.6 is needed because of IMPORTED_TARGET in pkg_check_modules().
+cmake_minimum_required(VERSION 3.6...3.14)
+# Ranges are supported from 3.12, set policy to current for < 3.12.
+if(${CMAKE_VERSION} VERSION_LESS 3.12)
+  cmake_policy(VERSION ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION})
+endif()
 
-include(GNUInstallDirs)
-find_package(PkgConfig REQUIRED)
-pkg_check_modules(LIBXDG_BASEDIR REQUIRED libxdg-basedir)
-pkg_check_modules(LIBCONFIG REQUIRED libconfig++)
+project(compilescript
+  VERSION 0.4.0
+  LANGUAGES CXX)
+# DESCRIPTION was introduced in version 3.9.
+if(NOT (${CMAKE_VERSION} VERSION_LESS 3.9))
+  set(PROJECT_DESCRIPTION
+    "Execute source files from compiled languages as scripts.")
+endif()
+
+option(WITH_MAN "Compile and install manpage." YES)
 
 set(CMAKE_CXX_STANDARD 14)
 set(CMAKE_CXX_STANDARD_REQUIRED ON)
 set(CMAKE_CXX_EXTENSIONS OFF)
 
-set(CMAKE_CXX_FLAGS_DEBUG
-    "${CMAKE_CXX_FLAGS_DEBUG} -Wall -Wextra -Wpedantic -ftrapv -fsanitize=undefined -g -Og -fno-omit-frame-pointer")
-
-include_directories(${PROJECT_BINARY_DIR})
-include_directories(${LIBXDG_BASEDIR_INCLUDE_DIRS})
-include_directories(${LIBCONFIG_INCLUDE_DIRS})
-
-link_directories(${LIBXDG_BASEDIR_LIBRARY_DIRS})
-link_directories(${LIBCONFIG_LIBRARY_DIRS})
-
-# Write version in header
-configure_file(
-    "${PROJECT_SOURCE_DIR}/src/version.hpp.in"
-    "${PROJECT_BINARY_DIR}/version.hpp"
-)
-
-file(GLOB sources src/*.cpp)
-add_executable(${CMAKE_PROJECT_NAME} "${sources}")
-target_link_libraries(${CMAKE_PROJECT_NAME}
-                      "${LIBXDG_BASEDIR_LDFLAGS} ${LIBCONFIG_LDFLAGS}"
-                      "-lstdc++fs")
-install(TARGETS ${CMAKE_PROJECT_NAME} DESTINATION ${CMAKE_INSTALL_BINDIR})
-
-set(WITH_MAN "YES" CACHE STRING "WITH_MAN defaults to \"YES\"")
-if (WITH_MAN)
-    add_custom_command(OUTPUT "${PROJECT_BINARY_DIR}/${CMAKE_PROJECT_NAME}.1"
-                       WORKING_DIRECTORY "${PROJECT_BINARY_DIR}"
-                       DEPENDS "${CMAKE_SOURCE_DIR}/${CMAKE_PROJECT_NAME}.1.adoc"
-                       COMMAND ${CMAKE_SOURCE_DIR}/build_manpage.sh
-                       ARGS ${PROJECT_VERSION})
-    add_custom_target(run ALL
-                      DEPENDS "${PROJECT_BINARY_DIR}/${CMAKE_PROJECT_NAME}.1")
-    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_PROJECT_NAME}.1
-            DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
+set(DEBUG_CXXFLAGS
+  "-Wall"
+  "-Wextra"
+  "-Wpedantic"
+  "-ftrapv"
+  "-fsanitize=undefined"
+  "-g"
+  "-Og"
+  "-fno-omit-frame-pointer")
+set(DEBUG_LDFLAGS
+  "-fsanitize=undefined")
+add_compile_options("$<$<CONFIG:Debug>:${DEBUG_CXXFLAGS}>")
+# add_link_options was introduced in version 3.13.
+if(${CMAKE_VERSION} VERSION_LESS 3.13)
+  set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${DEBUG_LDFLAGS}")
+else()
+  add_link_options("$<$<CONFIG:Debug>:${DEBUG_LDFLAGS}>")
+endif()
+
+add_subdirectory(src)
+
+if (WITH_MAN)
+  add_subdirectory(man)
 endif()

man/CMakeLists.txt

@@ -0,0 +1,14 @@
+include(GNUInstallDirs)
+
+add_custom_command(
+  OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.1"
+  WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
+  DEPENDS "${PROJECT_NAME}.1.adoc"
+  COMMAND "${PROJECT_SOURCE_DIR}/man/build_manpage.sh"
+  ARGS "${PROJECT_VERSION}")
+
+add_custom_target(man ALL
+  DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.1")
+
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.1
+  DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)

man/build_manpage.sh

@@ -3,9 +3,10 @@
 name="compilescript"
 
 if [ -n "${1}" ]; then
-    dir="$(dirname ${0})"
+    dir=$(dirname "${0}")
+    version=${1}
     cp -vf "${dir}/${name}.1.adoc" .
-    sed -Ei "s/(Revision: +)[0-9]+\.[0-9]\.[0-9]/\1${1}/" "${name}.1.adoc"
+    sed -Ei "s/(Revision: +)[0-9]+\.[0-9]\.[0-9]/\1${version}/" "${name}.1.adoc"
     a2x --doctype manpage --format manpage --no-xmllint "${name}.1.adoc"
 else
     echo "usage: ${0} VERSION" >&2

src/CMakeLists.txt

@@ -0,0 +1,22 @@
+include(GNUInstallDirs)
+
+find_package(PkgConfig REQUIRED)
+pkg_check_modules(libxdg-basedir REQUIRED IMPORTED_TARGET libxdg-basedir)
+pkg_check_modules(libconfig++ REQUIRED IMPORTED_TARGET libconfig++)
+
+# Write version in header
+configure_file("version.hpp.in" "${CMAKE_CURRENT_BINARY_DIR}/version.hpp")
+
+set(sources "main.cpp" "../xdgcfg/src/xdgcfg.cpp")
+
+add_executable(${CMAKE_PROJECT_NAME} "${sources}")
+
+target_include_directories(${PROJECT_NAME}
+  PRIVATE
+  "${PROJECT_SOURCE_DIR}/xdgcfg/include"
+  "${CMAKE_CURRENT_BINARY_DIR}")
+
+target_link_libraries(${CMAKE_PROJECT_NAME}
+  PRIVATE PkgConfig::libxdg-basedir PkgConfig::libconfig++ stdc++fs)
+
+install(TARGETS ${CMAKE_PROJECT_NAME} DESTINATION "${CMAKE_INSTALL_BINDIR}")

src/xdgcfg.cpp

@@ -1 +0,0 @@
-../xdgcfg/src/xdgcfg.cpp

src/xdgcfg.hpp

@@ -1 +0,0 @@
-../xdgcfg/src/xdgcfg.hpp

xdgcfg

@@ -1 +1 @@
-Subproject commit e22f82fc6f1c40cda3d3ce5e671299f26f622528
+Subproject commit 9337964266ae55415beaa7f517cc4240a259289a