From b442b75dfa453c1a8279b753d55ec5e372480785 Mon Sep 17 00:00:00 2001
From: tastytea <tastytea@tastytea.de>
Date: Wed, 9 May 2018 01:04:30 +0200
Subject: [PATCH] added gspell-1.8.0

---
 app-text/gspell/Manifest            |  1 +
 app-text/gspell/gspell-1.8.0.ebuild | 46 +++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+)
 create mode 100644 app-text/gspell/Manifest
 create mode 100644 app-text/gspell/gspell-1.8.0.ebuild

diff --git a/app-text/gspell/Manifest b/app-text/gspell/Manifest
new file mode 100644
index 000000000..88790eb1a
--- /dev/null
+++ b/app-text/gspell/Manifest
@@ -0,0 +1 @@
+DIST gspell-1.8.0.tar.xz 418460 BLAKE2B a7e03abf286c89756781941edff824d42790f19c1f3a3831c35781845f899842faa1c1eb439fea608893002d483283571d0ec9bb2f3fb58655ee8493c367fc3f SHA512 d55c0a159edccbf96afa727af3b440070d9b31c7f8db26ff0149d949f29eac4ecff01476f00b70e1d70bcc2ec873647fd42558b34c0a78f9c3b90679663de881
diff --git a/app-text/gspell/gspell-1.8.0.ebuild b/app-text/gspell/gspell-1.8.0.ebuild
new file mode 100644
index 000000000..fba4ec17f
--- /dev/null
+++ b/app-text/gspell/gspell-1.8.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="Spell check library for GTK+ applications"
+HOMEPAGE="https://wiki.gnome.org/Projects/gspell"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1" # subslot = libgspell-1 soname version
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~sparc x86 ~amd64-fbsd"
+
+IUSE="+introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	app-text/iso-codes
+	>=app-text/enchant-1.6.0
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.20:3[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.42.0:= )
+	vala? ( $(vala_depend) )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.25
+	>=sys-devel/gettext-0.19.4
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	virtx emake check
+}