net-im/gajim: fixed precis-i18n dependency

Package-Manager: Portage-2.3.51, Repoman-2.3.11
RepoMan-Options: --ignore-arches
Manifest-Sign-Key: 3555266864CA6D7FF45AA6E7CFC39497F1B26E07

net-im/gajim/Manifest

@@ -7,11 +7,12 @@ DIST gajim-1.0.3.tar.bz2 5964743 BLAKE2B af4bf2206a962eb68c4df09359fa3a0ccaca1e8
 DIST gajim-1.1.0.tar.bz2 8002680 BLAKE2B 651a08ee03db3ea0eeb19f8ea1b4663f103431a1b0a08ede37cd1cb7fa159d41c29450156fbab26091026985a518bcdbccc1fd21fa08fc173dd68b1c44d3f088 SHA512 47b18de111643eba382255e7c2d195b41f30bf15957cd27939ebd44eade7af1b9ebe50c30ca10f33ca36e879d309fc414369fd8ba2c725c336f38a3a0f88ba7c
 EBUILD gajim-1.0.3-r3.ebuild 2521 BLAKE2B 9026005e8fd95052c2612548d537eaab6c7edecd7b4ae09645e94b0fdff028d0b4b9e59474dcb37246e531d2aa041d43803de1db2084378b89a00469615dccdb SHA512 b74aa3883d92d3f4e1ed0904c78cb84ead2075bb0686ff8c60d63a7813f2739569c3f6db0c4eacb6fe0a464777bab51590336b5ec8be14f303c9f4e657c6638b
 EBUILD gajim-1.1.0-r1.ebuild 2732 BLAKE2B c00c63723daa10314453d2c74ce7d5a86b76021cde260350ea43518c16ae60400ed0e7645bdeb59ee2f9b5f57079dfc782e5db62d5ce5598b048ac9627ff0c5f SHA512 3af51fe2ea9a24fc9e9dfd9f957f49ca231dad5887d5b57d316c1298e467725436b4749b2cca97fd2c3a7731595b7d57f1b6f5b8c43f7adb35fbe5c774704cb0
+EBUILD gajim-1.1.0-r2.ebuild 2732 BLAKE2B 624958ec023d02b72b0f7975315f0fc3f063b5a244b7814475080decb78a49419af35c4d3bb6ede07a783f7c02aa38e31bb7754d611b2cf9dbb83a778f8bcd79 SHA512 8624f0dd6834fa129f2b52069492f4abbd5aabdf6df911e487a8e0d85c3d693dea15020c7d1c49bcafae40e3b7e2d0db017905454f9405b40eb2d35fe047e4b3
 MISC metadata.xml 807 BLAKE2B 1fd3f760c7dbc30a7396142f2fb2abe8fb896757a1b36cb9fb77db41ba9f825d5ea72bd1f7038a888738f81d4cf09a0fc8cb818dd769b34f1c76b573d200cfff SHA512 d7f93ff96e63bba7ef947bfc69019cad0b22fd2b2c0b65cbe4653a632759bf52849f46ec0c082bbb49a8dc32211c5c89ba800837c53f0642970b83002cb32787
 -----BEGIN PGP SIGNATURE-----
 
-iHUEAREIAB0WIQQ1VSZoZMptf/RapufPw5SX8bJuBwUCW+I0CwAKCRDPw5SX8bJu
+iHUEAREIAB0WIQQ1VSZoZMptf/RapufPw5SX8bJuBwUCW+N9xwAKCRDPw5SX8bJu
-B8zpAP9jyUZNj2Sy5bOD4/AIcKsyDSwrrCDkUwdOV5wgXtFPLAD/UgkIxiFLT7md
+Bxm2AP4nNq5pkuBdQWeUT/pySxU8eAry1cLpVqHMqLIK4mNHBgD/V0Kch0+HSraM
-Ztv71tbnRnvjf0+w5jY6jNbhTE09dJY=
+JZfFargTOXh2aEbuQTxNuuMMkn/LXvo=
-=VTtY
+=Srst
 -----END PGP SIGNATURE-----

net-im/gajim/gajim-1.1.0-r2.ebuild

@@ -0,0 +1,96 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="sqlite,xml"
+DISTUTILS_SINGLE_IMPL=1
+
+inherit gnome2-utils distutils-r1 eapi7-ver xdg-utils
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="https://www.gajim.org/"
+SRC_URI="https://www.gajim.org/downloads/$(ver_cut 1-2)/${P}.tar.bz2"
+#https://ftp.gajim.org/plugins_1.1_zip/plugin_installer.zip"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gpg +crypt remote idle jingle keyring networkmanager upnp geoclue spell +webp rst omemo"
+
+COMMON_DEPEND="
+	dev-libs/gobject-introspection[cairo,${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	>=dev-util/intltool-0.40.1
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=dev-python/python-nbxmpp-0.6.8[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	>=dev-python/cssutils-1.0.2[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/precis-i18n[${PYTHON_USEDEP}]
+	dev-python/pycurl[${PYTHON_USEDEP}]
+	crypt? ( dev-python/pycryptodome[${PYTHON_USEDEP}] )
+	gpg? ( >=dev-python/python-gnupg-0.4.0[${PYTHON_USEDEP}] )
+	idle? ( x11-libs/libXScrnSaver )
+	remote? (
+		>=dev-python/dbus-python-1.2.0[${PYTHON_USEDEP}]
+		dev-libs/dbus-glib
+	)
+	rst? ( dev-python/docutils[${PYTHON_USEDEP}] )
+	keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
+	jingle? (
+		net-libs/farstream:0.2[introspection]
+		media-libs/gstreamer:1.0[introspection]
+		media-libs/gst-plugins-base:1.0[introspection]
+		media-libs/gst-plugins-ugly:1.0
+	)
+	networkmanager? ( net-misc/networkmanager[introspection] )
+	upnp? ( net-libs/gupnp-igd[introspection] )
+	geoclue? ( app-misc/geoclue[introspection] )
+	spell? (
+		app-text/gspell[introspection]
+		app-text/hunspell
+	)
+	omemo? (
+		dev-python/python-axolotl[${PYTHON_USEDEP}]
+		dev-python/qrcode[${PYTHON_USEDEP}]
+	)
+	webp? ( dev-python/pillow[${PYTHON_USEDEP}] )
+"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	use spell || eapply "${FILESDIR}/disable-gspell-1.1.0.patch"
+	use keyring || sed -i 's/keyring//' setup.cfg
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# Gajims build script compresses the man pages. Gentoo would like to
+	# compress them itself.
+	gunzip "${D}/usr/share/man/man1/gajim.1.gz"
+	gunzip "${D}/usr/share/man/man1/gajim-history-manager.1.gz"
+	use remote && gunzip "${D}/usr/share/man/man1/gajim-remote.1.gz"
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}