net-im/nheko: treeclean

git ebuild is now in ::guru

Signed-off-by: tastytea <tastytea@tastytea.de>

dev-python/pygls/pygls-1.0.0.ebuild.draft

@@ -0,0 +1,39 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+inherit distutils-r1
+
+DESCRIPTION="A pythonic generic language server"
+HOMEPAGE="
+	https://pygls.readthedocs.io/en/latest/
+	https://pypi.org/project/pygls/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="1"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-python/wheel[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	dev-python/lsprotocol
+	<dev-python/typeguard-3.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest

net-im/nheko/metadata.xml

@@ -1,15 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<maintainer type="person">
-		<email>gentoo@tastytea.de</email>
-		<name>Ronny (tastytea) Gutbrod</name>
-	</maintainer>
-	<upstream>
-		<remote-id type="github">Nheko-Reborn/nheko</remote-id>
-	</upstream>
-	<use>
-		<flag name="video">Enables video calls</flag>
-		<flag name="voip">Enables audio calls</flag>
-	</use>
-</pkgmetadata>

net-im/nheko/nheko-9999.ebuild

@@ -1,130 +0,0 @@
-# Copyright 2020-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake git-r3 optfeature xdg
-
-DESCRIPTION="Native desktop client for Matrix using Qt"
-HOMEPAGE="https://github.com/Nheko-Reborn/nheko"
-EGIT_REPO_URI="https://github.com/Nheko-Reborn/nheko.git"
-MY_DEP_URIS=(
-	"https://github.com/Nheko-Reborn/mtxclient.git"
-	"https://nheko.im/nheko-reborn/coeurl.git"
-)
-
-LICENSE="GPL-3 MIT"
-SLOT="0"
-KEYWORDS=""
-IUSE="X video voip"
-REQUIRED_USE="video? ( voip )"
-
-MY_GST_V="1.18"
-RDEPEND="
-	app-text/cmark:=
-	dev-cpp/qt-jdenticon
-	dev-db/lmdb:=
-	>=dev-db/lmdb++-1.0.0
-	dev-libs/libevent:=
-	dev-libs/libfmt:=
-	dev-libs/olm
-	>=dev-libs/openssl-1.1.0:=
-	>=dev-libs/qtkeychain-0.12.0:=
-	>=dev-libs/re2-0.2022.04.01:=
-	dev-libs/spdlog:=
-	dev-qt/qtconcurrent:5
-	dev-qt/qtdeclarative:5[widgets]
-	dev-qt/qtgraphicaleffects:5
-	dev-qt/qtgui:5[dbus,gif(+),jpeg,png]
-	dev-qt/qtimageformats
-	dev-qt/qtmultimedia:5[gstreamer,qml,widgets]
-	dev-qt/qtquickcontrols2:5[widgets]
-	dev-qt/qtsvg:5
-	net-misc/curl
-	virtual/notification-daemon
-	voip? (
-		>=media-plugins/gst-plugins-dtls-${MY_GST_V}
-		media-plugins/gst-plugins-libnice
-		>=media-plugins/gst-plugins-meta-${MY_GST_V}[opus]
-		>=media-plugins/gst-plugins-srtp-${MY_GST_V}
-		>=media-plugins/gst-plugins-webrtc-${MY_GST_V}
-		video? (
-			>=media-libs/gst-plugins-base-${MY_GST_V}[opengl]
-			>=media-plugins/gst-plugins-meta-${MY_GST_V}[v4l,vpx]
-			>=media-plugins/gst-plugins-qt5-${MY_GST_V}
-			X? (
-				>=media-plugins/gst-plugins-ximagesrc-${MY_GST_V}
-				x11-libs/libxcb:=
-				x11-libs/xcb-util-wm
-			)
-		)
-	)
-"
-DEPEND="
-	dev-cpp/nlohmann_json
-	${RDEPEND}
-"
-BDEPEND="
-	dev-qt/linguist-tools:5
-	|| (
-		app-text/asciidoc
-		dev-ruby/asciidoctor
-	)
-"
-
-src_unpack() {
-	# Unpack dependencies first. The commit ID of the repo used in the last call
-	# to git-r3_src_unpack is stored.
-	for repo_uri in ${MY_DEP_URIS[@]}; do
-		EGIT_REPO_URI="${repo_uri}" EGIT_CHECKOUT_DIR="${WORKDIR}/${repo_uri##*/}" git-r3_src_unpack
-	done
-
-	git-r3_src_unpack
-}
-
-src_prepare() {
-	# Don't try to download mtxclient and coeurl.
-	sed -Ei '/GIT_(REPOSITORY|TAG)/d' CMakeLists.txt || die
-	sed -Ei '/GIT_(REPOSITORY|TAG)/d' ../mtxclient.git/CMakeLists.txt || die
-
-	mkdir -p "${WORKDIR}/${P}_build/_deps" || die
-	mv ../mtxclient.git "${WORKDIR}/${P}_build/_deps/matrixclient-src" || die
-	mv ../coeurl.git "${WORKDIR}/${P}_build/_deps/coeurl-src" || die
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	local -a mycmakeargs=(
-		"-DUSE_BUNDLED_MTXCLIENT=ON"
-		"-DUSE_BUNDLED_COEURL=ON"
-		"-DBUILD_SHARED_LIBS=OFF"
-		"-DVOIP=$(usex voip)"
-	)
-	if use video && use X; then
-		mycmakeargs+=("-DSCREENSHARE_X11=yes")
-	else
-		mycmakeargs+=("-DSCREENSHARE_X11=no")
-	fi
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	# Remove stuff from bundled libs.
-	rm -r "${D}/usr/$(get_libdir)" || die
-	rm -r "${D}/usr/include" || die
-}
-
-pkg_postinst() {
-	optfeature "audio & video file playback support" \
-		"media-plugins/gst-plugins-meta[ffmpeg]"
-	optfeature "secrets storage support other than kwallet (gnome-keyring or keepassxc)" \
-		"dev-libs/qtkeychain[gnome-keyring]"
-	optfeature "additional, less common, image format support" \
-		"kde-frameworks/kimageformats"
-
-	xdg_pkg_postinst
-}

profiles/package.mask

@@ -1,8 +1,3 @@
 # tastytea <gentoo@tastytea.de> (2023-02-20)
 # is in ::gentoo now, removal on 2023-03-20
 dev-cpp/curlpp
-
-# tastytea <gentoo@tastytea.de> (2023-02-05)
-# Live ebuild is in ::guru[1] now, removal on 2023-03-05
-# [1] <https://wiki.gentoo.org/wiki/Project:GURU>
-net-im/nheko